Spis treści

# X.WYSZUKAJ

Wyszukuje wartość w macierzy i zwraca odwołanie do komórki lub zakresu komórek.

Funkcja X.WYSZUKAJ to nowoczesny i elastyczny zamiennik starszych funkcji, takich jak WYSZUKAJ.PIONOWO, WYSZUKAJ.POZIOMO i WYSZUKAJ. X.WYSZUKAJ obsługuje dopasowania przybliżone i dokładne, symbole wieloznaczne (* ?) lub wyrażenia regularne dla dopasowań częściowych oraz wyszukiwania w zakresach pionowych i poziomych. X.WYSZUKAJ umożliwia wyszukiwanie odwrotne i oferuje szybkie wyszukiwanie binarne podczas pracy z dużymi zbiorami danych.

### Składnia

X.WYSZUKAJ( [Kryterium wyszukiwania]; Macierz wyszukiwania; Macierz wynikowa [; [Wynik, jeśli nie znaleziono] [; [Tryb dopasowania] [; Tryb wyszukiwania]]]])

Kryterium wyszukiwania: (opcjonalne) wartość dowolnego typu do wyszukania w Macierzy. Jeśli zostanie pominięta, funkcja X.WYSZUKAJ zwraca puste komórki znalezione w Macierzy wyszukiwania.

Macierz wyszukiwania: jest odniesieniem do macierzy do przeszukania. Macierz musi być jednowymiarową i musi być zawarta tylko w jednym arkuszu.

Macierz wynikowa: jest odniesieniem do macierzy lub zakresu do zwrócenia.

Jeśli Macierz wynikowa jest zakresem komórek, funkcję X.WYSZUKAJ należy wprowadzić jako formułę macierzy.

Wynik, jeśli nie znaleziono: tekst lub treść komórki, która ma zostać zwrócona, jeśli nie zostanie znaleziona wartość Wyszukaj. Jeśli nie znaleziono prawidłowego dopasowania i pominięto Wynik, jeśli nie znaleziono, funkcja zwraca błąd #N/D.

Tryb dopasowania: (opcjonalnie) określa typ dopasowania. Wartości mogą być:

- 0: dokładne dopasowanie (domyślnie). Jeśli nie znaleziono wartości Kryterium wyszukiwania i pominięto tekst Wynik, jeśli nie znaleziono, zwróć błąd #N/D.

- -1: próba dokładnego dopasowania. Jeśli wartość Kryterium wyszukiwania nie zostanie znaleziona, zwróć następny mniejszy element.

- 1: próba dokładnego dopasowania. Jeśli wartość Kryterium wyszukiwania nie zostanie znaleziona, zwróć następny większy element.

- 2: dopasowanie wieloznaczne, w którym znaki * (wiele znaków), ? (pojedynczy znak) i ~ mają specjalne znaczenie.

- 3: dopasowanie wyrażenia regularnego.

Tryb wyszukiwania: (opcjonalnie) określa używany tryb wyszukiwania.

- 1: zwraca pierwsze wystąpienie zaczynając od pierwszego elementu Macierz wyszukiwania (domyślnie).

- -1: wyszukiwanie wsteczne. Zwraca pierwsze wystąpienie, zaczynając od ostatniego elementu macierzy Macierz wyszukiwania.

- 2: wyszukiwanie binarne polegające na sortowaniu Macierzy wyszukiwania w porządku rosnącym. Jeśli nie zostaną posortowane, zwrócone zostaną nieprawidłowe wyniki.

- -2: wyszukiwanie binarne polegające na sortowaniu Macierzy wyszukiwania w porządku malejącym. Jeśli nie zostaną posortowane, zwrócone zostaną nieprawidłowe wyniki.

Wartości 2 i 3 w Trybie dopasowania nie można łączyć z wyszukiwaniem binarnym (wartość Trybu wyszukiwania 2 lub -2).

Można pominąć dowolny z opcjonalnych argumentów. Opcjonalny argument wymaga obecności wszystkich poprzedzających separatorów.

### Przykłady

Załóżmy, że zbudowaliśmy małą tabelę bazy danych zajmującą zakres komórek A1:DO4 i zawierającą podstawowe informacje o 118 pierwiastkach chemicznych. Pierwsza kolumna zawiera nagłówki wierszy „Pierwiastek”, „Symbol”, „Liczba atomowa” i „Względna masa atomowa”. Kolejne kolumny zawierają odpowiednie informacje dla każdego z pierwiastków, uporządkowane od lewej do prawej według liczby atomowej. Na przykład komórki B1:B4 zawierają „wodór”, „H”, „1” i „1,008”, podczas gdy komórki DO1:DO4 zawierają „Oganeson”, „Og”, „118” i „294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Pierwiastek | Wodór | Hel | Lit | ... | Oganeson
2 | Symbol | H | He | Li | ... | Og
3 | Liczba atomowa | 1 | 2 | 3 | ... | 118
4 | Względna masa atomowa | 1.008 | 4.0026 | 6.94 | ... | 294

{=X.WYSZUKAJ("Liczba atomowa";A2:A4;A2:DO4)} zwraca macierz

Liczba atomowa | 1 | 2 | 3 | ... | 118

{=X.WYSZUKAJ("Hel";B1:DO1;B1:DO4)} zwraca macierz

Hel
He
2
4.0026

{=X.WYSZUKAJ("Kryptonit";B1:DO1;B1:DO4;"Nieznany element") zwraca macierz {"Nieznany element","Nieznany element","Nieznany element","Nieznany element"}.

#### Szczegóły techniczne

Ta funkcja jest dostępna od wersji 24.8 LibreOffice.

Ta funkcja NIE jest częścią standardu Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Przestrzeń nazw to

COM.MICROSOFT.XLOOKUP

Tematy pokrewne

X.DOPASUJ

Strona wiki X.WYSZUKAJ.

Prosimy o wsparcie!