Inhoud

# Statistische functies - deel één

## AANTALLEN.ALS

Geeft het aantal cellen die aan criteria in meerdere bereiken voldoen.

## AANTAL

Telt hoeveel getallen een lijst met argumenten bevat. Tekstitems worden genegeerd.

#### Syntaxis

AANTAL(Argument 1 [; Argument 2 [; … [; Argument 255]]])

Argument 1; Argument 2; … ; Argument 255 zijn getallen, tekst, verwijzingen naar cellen of naar celbereiken van getallen of tekst.

Deze functie negeert elke tekst of lege cel binnen een gegevensbereik. Als u verkeerde resultaten van deze functie vermoedt, zoek dan naar tekst in de gegevensbereiken. Gebruik de functie Waardemarkering om tekstinhoud in een gegevensbereik te markeren.

#### Voorbeeld

De items 2, 4, 6 en "acht" in de velden Waarde 1-4 moeten worden meegeteld.

=AANTAL(2;4;6;"acht") = 3. De telling van getallen is daarom 3.

## AANTAL.ALS

Geeft het aantal cellen terug dat voldoet aan bepaalde criteria in een celbereik.

#### Syntaxis

AANTAL.ALS(Bereik; Criterium)

Bereik is het bereik waarop het criterium toegepast moeten worden.

Criterium: Een criterium is een tekstuele expressie die is berekend op basis van een enkele celreferentie, formule, getal of tekst. Het wordt gebruikt in vergelijkingen met celinhoud.

Een verwijzing naar een lege cel wordt geïnterpreteerd als de numerieke waarde 0.

Een overeenkomende uitdrukking kan zijn:

- Een getal of logische waarde. Een overeenkomende celinhoud is gelijk aan het getal of de logische waarde.

- Een waarde die begint met een vergelijker (, <=, =, >, >=, <>).

  Voor =: als de waarde leeg is, komt deze overeen met lege cellen.

  Voor <> geldt dat als de waarde leeg is, deze overeenkomt met niet-lege cellen.

  Als de waarde voor <> niet leeg is, komt deze overeen met alle celinhoud behalve de waarde, inclusief lege cellen.

  Opmerking: "=0" komt niet overeen met lege cellen.

  Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of één van de subtypen ervan en de eigenschap Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn is aangevinkt, de vergelijking vindt plaats met de volledige celinhoud, als niet aangevinkt, wordt er vergeleken met elk subgedeelte van het veld dat aan de criteria voldoet. Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of als één van de subtypes ervan van toepassing is.

- Andere tekstwaarde. Als de eigenschap Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn waar is , is de vergelijking met de gehele celinhoud. Als deze niet waar is, wordt er met elk subdeel van het veld vergeleken dat aan de criteria voldoet. De expressie kan tekst, getallen, reguliere expressies of jokertekens bevatten (indien ingeschakeld in berekeningsopties).

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - dialoogvenster Berekenen .

Wanneer u functies gebruikt waarbij één of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een taalinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Voorbeeld

A1:A10 is een celbereik dat de getallen 2000 tot en met 2009 bevat. Cel B1 bevat het getal 2006. In cel B2 voert u een formule in:

=AANTAL.ALS(A1:A10;2006) - geeft 1 terug.

=AANTAL.ALS(A1:A10;B1) - geeft 1 terug.

=AANTAL.ALS(A1:A10;">=2006") - geeft 4 terug.

=AANTAL.ALS(A1:A10;"<"&B1) - waar B1 2006 bevat - geeft 6 terug.

=AANTAL.ALS(A1:A10;C2), waar cel C2 de tekst >2006 bevat, telt het aantal cellen in het bereik A1:A10 die >2006 zijn

Alleen negatieve getallen tellen: =AANTAL.ALS(A1:A10;"<0")

## AANTAL.LEGE.CELLEN

Geeft het aantal lege cellen terug.

#### Syntaxis

AANTAL.LEGE.CELLEN(Bereik)

Geeft het aantal lege cellen in het celbereik Bereik terug.

#### Voorbeeld

=AANTAL.LEGE.CELLEN(A1:B2) geeft 4 terug als de cellen A1, A2, B1 en B2 allemaal leeg zijn.

## AANTALARG

Telt hoeveel waardes een lijst met argumenten bevat. Tekstitems worden ook geteld, zelfs wanneer ze een lege tekenreeks met lengte 0 bevatten. Als een argument een matrix of verwijzing is, worden lege cellen in de matrix of verwijzing genegeerd.

#### Syntaxis

AANTALARG(Argument 1 [; Argument 2 [; … [; Argument 255]]])

Argument 1; Argument 2; … ; Argument 255 zijn getallen, tekst, verwijzingen naar cellen of naar celbereiken van getallen of tekst.

#### Voorbeeld

De items 2, 4, 6 en "acht" in de velden Waarde 1-4 moeten worden meegeteld.

=AANTALARG(2;4;6;"acht") = 4. De telling van waardes is daarom 4.

## B

Geeft de kans van een steekproef met binomiale verdeling.

#### Syntaxis

B(Experimenten; Kans; Ondergrens; Bovengrens (optioneel))

Experimenten is het aantal onafhankelijke experimenten.

Kans is de kans op succes bij elk experiment.

Ondergrens definieert de ondergrens voor het aantal pogingen.

Bovengrens (optioneel) definieert de bovengrens voor het aantal experimenten.

#### Voorbeeld

Hoe groot is de kans dat er twee keer een zes gegooid wordt bij tien worpen van een dobbelsteen? De kans op een zes (of een willekeurig ander getal) is 1/6. De volgende formule combineert deze factoren:

=B(10;1/6;2) geeft een waarschijnlijkheid van 29% afgerond.

## BETA.INV

Retourneert de inverse van de cumulatieve bèta-kansdichtheidsfunctie.

#### Syntaxis

BETA.INV(Getal; Alfa; Beta ; Ondergrens (optioneel); Bovengrens (optioneel))

Getal is de kans die is gekoppeld aan de bètaverdeling voor de gegeven argumenten Alfa en Beta.

Alfa is een strikt positieve parameter van de bètaverdeling.

Beta is een strikt positieve parameter van de bètaverdeling.

Ondergrens (optioneel) is de ondergrens van het uitvoerbereik van de functie. Indien weggelaten, is de standaardwaarde 0.

Bovengrens (optioneel) is de bovengrens van het uitvoerbereik van de functie. Indien weggelaten, is de standaardwaarde 1.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=BETA.INV(0,5;5;10) retourneert de waarde 0,3257511553.

BETA.INV Wiki-pagina

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.BETA.INV

## BETA.VERD

Geeft als resultaat de bètafunctie.

Deze functie is beschikbaar sinds LibreOffice 4.2.

#### Syntaxis

BETA.VERD(Getal; Alfa; Beta; Cumulatief ; Ondergrens (optioneel); Bovengrens (optioneel))

Getal (vereist) is de waarde tussen Ondergrens en Bovengrens waarop de functie geëvalueerd moet worden.

Alfa (vereist) is een parameter voor de verdeling.

Beta (vereist)is een parameter voor de verdeling.

Cumulatief (vereist) mag 0 of Onwaar zijn om de kansdichtheidsfunctie te berekenen. Elke andere waarde of WAAR of weggelaten berekent de cumulatieve verdelingsfunctie.

Ondergrens (optioneel) is de ondergrens voor Getal.

Bovengrens (optioneel) is de bovengrens voor Getal.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=BETA.VERD(2;8;10;1;1;3) geeft de waarde 0,6854706 terug

=BETA.VERD(2;8;10;0;1;3) geeft de waarde 1,4837646 terug

#### Technische informatie

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.BETA.DIST

## BETAINV

Retourneert de inverse van de cumulatieve beta-kansdichtheidsfunctie.

#### Syntaxis

BETAINV(Getal; Alfa; Beta; Ondergrens (optioneel); Bovengrens (optioneel)

Getal is de kans die is gekoppeld aan de bètaverdeling voor de gegeven argumenten Alfa en Beta.

Alfa is een strikt positieve parameter van de bètaverdeling.

Beta is een strikt positieve parameter van de bèta-distributie.

Ondergrens (optioneel) is de ondergrens van het uitvoerbereik van de functie. Indien weggelaten, is de standaardwaarde 0.

Bovengrens (optioneel) is de bovengrens van het uitvoerbereik van de functie. Indien weggelaten, is de standaardwaarde 1.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=BETAINV(0,5;5;10) geeft de waarde 0,3257511553 terug.

Wiki-pagina BETAINV

## BETAVERD

Geeft als resultaat de bètafunctie.

#### Syntaxis

BETAVERD(Getal; Alfa; Beta; Ondergrens (optioneel); Bovengrens (optioneel); Cumulatief (optioneel))

Getal is de waarde tussen Ondergrens en Bovengrens waarop de functie geëvalueerd moet worden.

Alfa is een parameter voor de verdeling.

Beta is een parameter voor de verdeling.

Ondergrens (optioneel) is de ondergrens voor Getal.

Bovengrens (optioneel) is de bovengrens voor Getal.

Cumulatief (optioneel) mag 0 of Onwaar zijn om de kansdichtheidsfunctie te berekenen. Elke andere waarde of WAAR of weggelaten berekent de cumulatieve verdelingsfunctie.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=BETAVERD(0,75;3;4) geeft de waarde 0,96 (afgerond) terug.

## BINOM.VERD

Geeft de binomiale waarschijnlijkheidsverdeling van individuele termen.

#### Syntaxis

BINOM.VERD(Aantal; Experimenten; Kans; Cumulatief)

Aantal is het aantal successen in een set experimenten.

Experimenten is het aantal onafhankelijke beproevingen.

Kans is de kans op succes bij elk experiment.

Cumulatief = 0 berekent de kans van één gebeurtenis en Cumulatief = 1 berekent de cumulatieve kans.

#### Voorbeeld

=BINOM.VERD(A1;12;0,5;0) toont (als de waardes 0 tot en met 12 zijn ingevoerd in A1) de mogelijkheden voor het 12 keer opgooien van een munt waarbij Kop exact het aantal keren zal vallen als werd ingevoerd in A1.

=BINOM.VERD(A1;12;0,5;1) toont de cumulatieve kansen voor dezelfde reeksen. Als bijvoorbeeld A1 = 4 is de cumulatieve kans van de reeks 0, 1, 2, 3 of 4 keer Kop (niet-exclusieve OF).

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.BINOM.DIST

## BINOMIALE.INV

Geeft als resultaat de kleinste waarde waarvoor de cumulatieve binomiale verdeling groter is dan of gelijk aan een grenswaarde.

#### Syntaxis

BINOMIALE.INV(Experimenten; Kans; Alfa)

Experimenten is het totaal aantal pogingen.

Kans is de kans op succes bij elk experiment.

Alfa De grenzen van een kansbereik dat wordt bereikt of overschreden.

#### Voorbeeld

=BINOMIALE.INV(8;0,6;0,9) geeft 7 terug, de kleinste waarde waarvoor de cumulatieve binomiale verdeling groter is dan of gelijk aan een criteriumwaarde.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.BINOM.INV

## BINOMIALE.VERD

Geeft de binomiale waarschijnlijkheidsverdeling van individuele termen.

#### Syntaxis

BINOMIALE.VERD(Aantal; Experimenten; Kans; Cumulatief)

Aantal is het aantal successen in een set experimenten.

Experimenten is het aantal onafhankelijke experimenten.

Kans is de kans op succes bij elk experiment.

Cumulatief = 0 berekent de kans van één gebeurtenis en Cumulatief = 1 berekent de cumulatieve kans.

#### Voorbeeld

=BINOMIALE.VERD(A1;12;0,5;0) toont (als de waardes 0 tot en met 12 zijn ingevoerd in A1) de mogelijkheden voor het 12 keer opgooien van een munt waarbij Kop exact het aantal keren zal vallen als werd ingevoerd in A1.

=BINOMIALE.VERD(A1;12;0,5;1) toont de cumulatieve kansen voor dezelfde reeksen. Als bijvoorbeeld A1 = 4 is de cumulatieve kans van de reeks 0, 1, 2, 3 of 4 keer Kop (niet-exclusieve OF).

## CHI.KWADRAAT

Geeft de kanswaarde van het aangegeven Chi-kwadraat dat een hypothese bevestigd wordt. CHI.KWADRAAT vergelijkt de te geven Chi-kwadraatswaarde voor een willekeurige steekproef die berekend wordt uit de som van (waargenomen waarde-verwachte waarde)^2/verwachte waarde voor alle waardes met de theoretische Chi-kwadraatsverdeling, en haalt hieruit de foutkans voor de hypothese die getest moet worden.

De kans die bepaald wordt door CHI.KWADRAAT kan ook door CHI.TOETS bepaald worden.

#### Syntaxis

CHI.KWADRAAT(Getal; Vrijheidsgraden)

Getal is de chi-kwadraatswaarde van de willekeurige steekproef die gebruikt wordt om de foutkans te bepalen.

Vrijheidsgraden zijn de vrijheidsgraden van het experiment.

#### Voorbeeld

=CHI.KWADRAAT(13,27; 5) is gelijk aan 0,02 (afgerond).

Als de Chi-kwadraatswaarde van de willekeurige steekproef 13,27 is en het experiment 5 vrijheidsgraden heeft, dan wordt de hypothese bevestigd met een foutkans van 2%.

## CHI.KWADRAAT.INV

Geeft de inverse van de eenzijdige kans van de chi-kwadraatsverdeling.

#### Syntaxis

CHI.KWADRAAT.INV(Getal; Vrijheidsgraden)

Getal is de waarde van de foutkans.

Vrijheidsgraden zijn de vrijheidsgraden van het experiment.

#### Voorbeeld

Een dobbelsteen wordt 1020 keer geworpen. De getallen 1 tot en met 6 op de dobbelsteen komen 195, 151, 148, 189, 183 en 154 keer boven (observatiewaardes). De hypothese dat er niet met de dobbelsteen geknoeid is, moet getest worden.

De Chi-kwadraatsverdeling van de willekeurige steekproef wordt bepaald door de bovenstaande formule. Aangezien de verwachte waarde voor een bepaald getal op de dobbelsteen voor n worpen n keer 1/6 is, dus 1020/6 = 170, geeft de formule een Chi-kwadraatswaarde van 13,27.

Als het (waargenomen) Chi-kwadraat groter is dan of gelijk is aan het (theoretische) Chi-kwadraat CHI.KWADRAAT.INV, wordt de hypothese verworpen, aangezien de afwijking tussen theorie en experiment te groot is. Is het waargenomen Chi-kwadraat minder dan CHI.KWADRAAT.INV, dan wordt de hypothese bevestigd met de aangegeven foutkans.

=CHI.KWADRAAT.INV(0,05;5) geeft 11,07 (afgerond) terug.

=CHI.KWADRAAT.INV(0,02;5) geeft 13,39 (afgerond) terug.

Als de foutkans 5% is, is de dobbelsteen niet zuiver. Is de foutkans 2%, dan is er geen reden te geloven dat er met de dobbelsteen geknoeid is.

## CHI.TOETS

Geeft de kans op een afwijking van een willekeurige verdeling van twee testreeksen op basis van de chi-kwadraatstest voor onafhankelijkheid. CHI.TOETS geeft de chi-kwadraatsverdeling van de gegevens.

De kans die bepaald wordt door CHI.TOETS, kan ook met CHI.KWADRAAT bepaald worden. In dat geval moet het Chi-kwadraat van de willekeurige steekproef als parameter doorgegeven worden in plaats van de gegevensrij.

#### Syntaxis

CHI.TOETS(Waarnemingen; Verwacht)

Waarnemingen is de matrix van de waarnemingen.

Verwacht is het bereik van de verwachte waardes.

#### Voorbeeld

| Gegevens_B (Waarnemingen) | Gegevens_E (Verwacht)
1 | 195 | 170
2 | 151 | 170
3 | 148 | 170
4 | 189 | 170
5 | 183 | 170
6 | 154 | 170

=CHI.TOETS(A1:A6;B1:B6) is gelijk aan 0,02 (afgerond). Dit is de waarschijnlijkheid die de geobserveerde gegevens voor de theoretische chi-kwadraat verdeling verschaffen.

## CHIKW.INV

Geeft de inverse van de linkszijdige waarschijnlijkheid van de chi-kwadraatsverdeling.

#### Syntaxis

CHIKW.INV(Kans; Vrijheidsgraden)

Kans is de kanswaarde waarvoor de inverse van de chi-kwadraat verdeling moet worden berekend.

Vrijheidsgraden zijn de vrijheidsgraden voor de chi-kwadraat functie.

#### Voorbeeld

=CHIKW.INV(0,5;1) geeft 0,4549364231 terug.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.CHISQ.INV

## CHIKW.INV.RECHTS

Geeft de inverse van de eenzijdige kans van de chi-kwadraatsverdeling.

#### Syntaxis

CHIKW.INV.RECHTS(Kans; Vrijheidsgraden)

Kans is de waarde van de foutkans.

Vrijheidsgraden zijn de vrijheidsgraden van het experiment.

#### Voorbeeld

Een dobbelsteen wordt 1020 keer geworpen. De getallen 1 tot en met 6 op de dobbelsteen komen 195, 151, 148, 189, 183 en 154 keer boven (observatiewaardes). De hypothese dat er niet met de dobbelsteen geknoeid is, moet getest worden.

De Chi-kwadraatsverdeling van de willekeurige steekproef wordt bepaald door de bovenstaande formule. Aangezien de verwachte waarde voor een bepaald getal op de dobbelsteen voor n worpen n keer 1/6 is, dus 1020/6 = 170, geeft de formule een Chi-kwadraatswaarde van 13,27.

Als het (waargenomen) Chi-kwadraat groter is dan of gelijk is aan het (theoretische) Chi-kwadraat CHI.KWADRAAT.INV, wordt de hypothese verworpen, aangezien de afwijking tussen theorie en experiment te groot is. Is het waargenomen Chi-kwadraat minder dan CHI.KWADRAAT.INV, dan wordt de hypothese bevestigd met de aangegeven foutkans.

=CHIKW.INV.RECHTS(0,05;5) geeft 11,0704976935 terug.

=CHIKW.INV.RECHTS(0,02;5) geeft 13,388222599 terug.

Als de foutkans 5% is, is de dobbelsteen niet zuiver. Is de foutkans 2%, dan is er geen reden te geloven dat er met de dobbelsteen geknoeid is.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.CHISQ.INV.RT

## CHIKW.TEST

Geeft de kans op een afwijking van een willekeurige verdeling van twee testreeksen op basis van de chi-kwadraatstest voor onafhankelijkheid. CHIKW.TEST geeft de chi-kwadraatsverdeling van de gegevens.

De kans die bepaald wordt door CHIKW.TEST, kan ook met CHIKW.VERD bepaald worden. In dat geval moet het Chi-kwadraat van de willekeurige steekproef als parameter doorgegeven worden in plaats van de gegevensrij.

#### Syntaxis

CHIKW.TEST(Waarnemingen; Verwacht)

Waarnemingen is de matrix van de waarnemingen.

Verwacht is het bereik van de verwachte waardes.

#### Voorbeeld

| Gegevens_B (Waarnemingen) | Gegevens_E (Verwacht)
1 | 195 | 170
2 | 151 | 170
3 | 148 | 170
4 | 189 | 170
5 | 183 | 170
6 | 154 | 170

=CHIKW.TEST(A1:A6;B1:B6) is gelijk aan 0,0209708029. Dit is de waarschijnlijkheid die de geobserveerde gegevens voor de theoretische chi-kwadraat verdeling verschaffen.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.CHISQ.TEST

## CHIKW.VERD

Geeft de waarde van de kansdichtheidsfunctie of de cumulatieve verdelingsfunctie voor de chi-kwadraat verdeling terug

#### Syntaxis

CHIKW.VERD(Getal; Vrijheidsgraden; Cumulatief)

Getal is de chi-kwadraatswaarde van de willekeurige steekproef die gebruikt wordt om de foutkans te bepalen.

Vrijheidsgraden zijn de vrijheidsgraden van het experiment.

Cumulatief mag 0 of Onwaar zijn om de kansdichtheidsfunctie te berekenen. Elke andere waarde of WAAR of weggelaten berekent de cumulatieve verdelingsfunctie.

#### Voorbeeld

=CHIKW.VERD(3; 2; 0) is gelijk aan 0,1115650801, dit is de densiteit van de waarschijnlijkheid met 2 graden vrijheid voor x = 3.

=CHIKW.VERD(3; 2; 1) is gelijk aan 0,7768698399, dit is de cumulatieve distributie met 2 graden vrijheid voor de waarde x = 3.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.CHISQ.DIST

## CHIKW.VERD.RECHTS

Geeft de waarschijnlijkheidswaarde van het aangegeven Chi-kwadraat dat een hypothese bevestigd wordt. CHIKW.VERD.RECHTS vergelijkt de te geven Chi-kwadraatswaarde voor een willekeurige steekproef die berekend wordt uit de som van (waargenomen waarde-verwachte waarde)^2/verwachte waarde voor alle waardes met de theoretische Chi-kwadraatsverdeling, en haalt hieruit de foutkans voor de hypothese die getest moet worden.

De kans die bepaald wordt door CHIKW.VERD.RECHTS kan ook door CHI.TOETS bepaald worden.

#### Syntaxis

CHIKW.VERD.RECHTS(Getal; Vrijheidsgraden)

Getal is de chi-kwadraatswaarde van de willekeurige steekproef die gebruikt wordt om de foutkans te bepalen.

Vrijheidsgraden zijn de vrijheidsgraden van het experiment.

#### Voorbeeld

=CHIKW.VERD.RECHTS(13,27; 5) is gelijk aan 0,0209757694.

Als de Chi-kwadraatswaarde van de willekeurige steekproef 13,27 is en het experiment 5 vrijheidsgraden heeft, dan wordt de hypothese bevestigd met een foutkans van 2%.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.CHISQ.DIST.RT

## CHIKWADRINV

Geeft als resultaat de inverse van CHIKWADRVERD.

#### Syntaxis

CHIKWADRINV(Kans; Vrijheidsgraden)

Kans is de kanswaarde waarvoor de inverse van de chi-kwadraat verdeling moet worden berekend.

Vrijheidsgraden zijn de vrijheidsgraden voor de chi-kwadraat functie.

## CHIKWADRVERD

Geeft de waarde van de kansdichtheidsfunctie of de cumulatieve verdelingsfunctie voor de chi-kwadraat verdeling terug.

#### Syntaxis

CHIKWADRVERD(Getal; Vrijheidsgraden ; Cumulatief (optioneel))

Getal is de waarde waarvoor de functie moet worden berekend.

Vrijheidsgraden zijn de vrijheidsgraden voor de chi-kwadraat functie.

Cumulatief (optioneel): 0 of Onwaar berekent de kansdichtheidsfunctie. Elke andere waarde of WAAR of weggelaten berekent de cumulatieve verdelingsfunctie.

## EXPON.VERD

Geeft de exponentiële verdeling.

#### Syntaxis

EXPON.VERD(Getal; Lambda; Cumulatief)

Getal is de waarde van de functie.

Lambda is de parameterwaarde.

Cumulatief is een logische waarde die de vorm van de functie bepaalt. Cumulatief = 0 berekent de dichtheidsfunctie en Cumulatief = 1 berekent de verdeling.

#### Voorbeeld

=EXPON.VERD(3;0,5;1) geeft 0,78 (afgerond) terug.

## EXPON.VERD.N

Geeft de exponentiële verdeling terug

#### Syntaxis

EXPON.VERD.N(Getal; Lambda; Cumulatief)

Getal is de waarde van de functie.

Lambda is de parameterwaarde.

Cumulatief is een logische waarde die de vorm van de functie bepaalt. Cumulatief = 0 berekent de dichtheidsfunctie en Cumulatief = 1 berekent de verdeling.

#### Voorbeeld

=EXPON.VERD.N(3;0,5;1) geeft 0,7768698399 terug.

#### Technische informatie

Deze functie is beschikbaar sinds LibreOffice 4.2.

Deze functie maakt GEEN deel uit van de standaard Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula)-indeling. De naamruimte is

COM.MICROSOFT.EXPON.DIST

## R.KWADRAAT

Geeft het kwadraat van de Pearson-correlatiecoëfficiënt op basis van de gegeven waardes. R.KWADRAAT (ook wel vaststelling van coëfficiënten genoemd) is een maateenheid voor de nauwkeurigheid van een aanpassing, en kan gebruikt worden om een regressieanalyse te produceren.

#### Syntaxis

R.KWADRAAT(Gegevens Y; Gegevens X)

Gegevens Y is een matrix of bereik van gegevenspunten.

Gegevens X is een matrix of bereik van gegevenspunten.

#### Voorbeeld

=R.KWADRAAT(A1:A20;B1:B20) berekent de correlatie coëfficiënt voor beide gegevensverzamelingen in de kolommen A en B.

## SNIJPUNT

Berekent het punt waarop een regel de y-waardes zal doorsnijden met behulp van bekende x- en y-waardes.

#### Syntaxis

SNIJPUNT(Gegevens Y; Gegevens X)

Gegevens Y is de afhankelijke verzameling observaties of gegevens.

Gegevens X is de onafhankelijke verzameling van observaties of gegevens.

Hier moeten namen, matrixen of verwijzingen met getallen gebruikt worden. Getallen kunnen ook direct worden ingevoerd.

#### Voorbeeld

Wilt u het snijpunt berekenen, dan gebruikt u de cellen D3:D9 als de y-waarde en C3:C9 als de x-waarde uit de op pagina https://help.libreoffice.org/25.2/nl/text/scalc/01/04060108.html?DbPAR=CALC weergegeven tabel. De invoer is als volgt:

=SNIJPUNT(D3:D9;C3:C9) = 2,15 (afgerond).

Verwante onderwerpen

Functies per categorie

Help ons, alstublieft!